1

I'm using Google Finance calls in Google Sheets for some calculations.

I've got 2 formulas, one to find the low price, and one to find the high price from a certain date:

=MIN(INDEX(GOOGLEFINANCE("TSLA","low",7/23/2018,TODAY(),1),,2))

=MAX(INDEX(GOOGLEFINANCE("TSLA","high",7/23/2018,TODAY(),1),,2))

These work as I expect to show just the low/high price, but now I'd like to also have the associated timestamp in another column next to it.

So it would roughly look like this:

|Ticker | Low    | Low Date | High   | High Date |

| TSLA  | 176.99 | 6/3/2019 | 387.46 | 8/7/2018  |

1 Answer 1

1

={"TSLA", MIN(INDEX(GOOGLEFINANCE("TSLA", "low",  "7/23/2018", TODAY(), 1),, 2)),
  VLOOKUP(MIN(INDEX(GOOGLEFINANCE("TSLA", "low",  "7/23/2018", TODAY(), 1),, 2)), 
             {INDEX(GOOGLEFINANCE("TSLA", "low",  "7/23/2018", TODAY(), 1),, 2), 
                    GOOGLEFINANCE("TSLA", "low",  "7/23/2018", TODAY(), 1)}, 2, 0), 
          MAX(INDEX(GOOGLEFINANCE("TSLA", "high", "7/23/2018", TODAY(), 1),, 2)),
  VLOOKUP(MAX(INDEX(GOOGLEFINANCE("TSLA", "high", "7/23/2018", TODAY(), 1),, 2)), 
             {INDEX(GOOGLEFINANCE("TSLA", "high", "7/23/2018", TODAY(), 1),, 2), 
                    GOOGLEFINANCE("TSLA", "high", "7/23/2018", TODAY(), 1)}, 2, 0)}

0

2
  • Thanks! That works well -- I made a mistake in my initial post. In that the "low" part of the formula should be MIN( ) not MAX( ). Would you mind fixing in your answer and then I will accept? Jul 24, 2019 at 13:54
  • @mainstringargs sure, done
    – user0
    Jul 24, 2019 at 22:12

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.