How to repeat query for a range of data in google sheet

Question

I have this table in Google sheet:

Col A (Month)	Col B (Date)
January	1/1/2023
January	1/2/2023
January	1/3/2023

And I have another table:

Col C (Dept.)	Col D (KPI)
Dep1	KPI1
Dep1	KPI2
Dep2	KPI3

I want to repeat the first table for each item from the second table to be like:

Col E (Month)	Col F (Date)	Col G (Dept.)	Col H (KPI)
January	1/1/2023	Dep1	KPI1
January	1/2/2023	Dep1	KPI1
January	1/3/2023	Dep1	KPI1
January	1/1/2023	Dep1	KPI2
January	1/2/2023	Dep1	KPI2
January	1/3/2023	Dep1	KPI2
January	1/1/2023	Dep3	KPI3
January	1/2/2023	Dep3	KPI3
January	1/3/2023	Dep3	KPI3

I tried to work with query inside an array formula but it is not working.

Please Help,

Thank you,

Answer 1

Use reduce(), like this:

=query( 
  lambda( 
    table1, table2, 
    reduce( 
      A1:D1, sequence(rows(table1)), 
      lambda( 
        result, rowIndex, 
        { 
          result; 
          byrow( 
            table2, 
            lambda( 
              table2row, 
              { 
                index(table1, rowIndex), 
                table2row 
              }
            ) 
          ) 
        } 
      ) 
    ) 
  )( 
    filter(A2:B, len(A2:A)), filter(C2:D, len(C2:C)) 
  ), 
  "order by Col4 format Col2 'M/d/yyyy' ", 1
)